'WRITTEN BY ROGER CAMERON
'N0YOX@ILAND.NET
'BS1 REPEATER CONTROLLER


STARTOVER:
'/////0 = CHARACTER SPACE/////1 = DIT ///// 2 = DAH make sure to count 
'elements and enter value in the id for next statement 0  to 1 is 2 elements
EEPROM 0,(2,1,0,2,2,2,2,2,0,2,1,2,2,0,2,2,2,0,2,1,1,2,0,0,1,2,1)'N0YOX


'''''''''''''''''''''''WORD'''''''''''''''''''''''''''''''''''''
SYMBOL CHARACTER = W2
SYMBOL TIMER = W3
SYMBOL TOTIMER = W4
SYMBOL I = W5
SYMBOL TAILTIME = W6
'''''''''''''''''''''''''BYTE''''''''''''''''''''''''''''''''''''
SYMBOL TAILRQ = B1  'TAIL REQUIRED BIT
 

SYMBOL SOUT = 4 ' CHANGE TO PIN NUMBER THAT MATCHES YOUR BOARD SOUND OUT
SYMBOL COR = PIN5  ' CHANGE TO PIN NUMBER THAT MATCHES YOUR BOARD
SYMBOL FAN = 6  ' CHANGE TO PIN NUMBER THAT MATCHES YOUR BOARD
SYMBOL PTT = 7  ' CHANGE TO PIN NUMBER THAT MATCHES YOUR BOARD

      HIGH PTT

ID:
      HIGH PTT
      LOW FAN
      PAUSE 1000
      TIMER = 0

      FOR I = 0 TO 30 ' 30 IS THE NUMBER  OF ELEMENTS IN THE CALLSIGN - 1
      READ I, CHARACTER    'READS CW OUT OF DATA AREA
      GOSUB MORSE
      NEXT

      PAUSE 300
      LOW PTT

WAITT:
      PAUSE 100
      TIMER = TIMER + 1
      TIMER = TIMER MAX 5500
      IF COR = 1 THEN TX
      GOTO WAITT







CORE2:
      PAUSE 3000'SENT HERE BY TIME_OUT
      HIGH PTT
      GOSUB SIGTO
      TOTIMER = 0


CORE:
      TIMER = TIMER + 1
      IF TIMER > 5500 THEN ID ' CHANGE THE VALUE HERE TO CHANGE ID TIMER 5500 = 550 SECONDS
      IF COR = 1 THEN TX
      IF TAILRQ = 1 THEN TAIL
      LOW PTT
      PAUSE 100
      GOTO CORE

TX:
      TAILRQ = 1
      HIGH FAN
      HIGH PTT
      IF TOTIMER > 2000 THEN TIMOUT ' 1800'CHANGE THIS VALUE TO CHANGE TIME OUT TIMER 1800 = 180 SECONDS OR 10 = 1 SECOND
      TIMER = TIMER + 1
      PAUSE 100 
      TOTIMER = TOTIMER + 1
      GOTO CORE

TAIL:

      FOR I = 1 TO 35
      PAUSE 20
      IF COR = 1 THEN CORE
      NEXT
      TOTIMER = 0
      TAILRQ = 0
      SOUND SOUT,(110,18)' TAIL TONE 105 
      FOR I = 1 TO 100
      PAUSE 20
      IF COR = 1 THEN CORE
      NEXT

      LOW PTT
      GOTO CORE


MORSE:


      BRANCH CHARACTER,(SPACE,DIT,DAH)
      RETURN

      SPACE:
            SOUND SOUT, (0,15)
            RETURN


      DIT:
            SOUND SOUT, (99,5,0,5)'99 IS CWTONE
            RETURN

      DAH:
            SOUND SOUT, (99,15,0,5)'99 IS CWTONE
            RETURN


TIMOUT:

      GOSUB SIGTO
      LOW PTT
      TAILRQ = 0
 TIM:
	PAUSE 300
	IF COR = 0 THEN CORE2
	GOTO TIM


SIGTO:
      PAUSE 500
      FOR I = 0 to 4
      lookup I, (2,0,2,2,2),CHARACTER
      gosub Morse
      NEXT
      RETURN